pkgname=shinoa-git
pkgver=r4.4910fb5
pkgrel=1
pkgdesc='Minimal Telegram terminal client built with ncurses and TDLib'
arch=('x86_64')
url='https://git.mshq.dev/AxiFisk/shinoa'
license=('custom:unknown')
depends=('gcc-libs' 'glibc' 'ncurses' 'openssl' 'zlib')
makedepends=('cmake' 'git' 'gperf')
provides=('shinoa')
conflicts=('shinoa')
source=('git+https://git.mshq.dev/AxiFisk/shinoa.git')
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/shinoa"
  printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cmake -S "$srcdir/shinoa" -B "$srcdir/build" \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr
  cmake --build "$srcdir/build"
}

package() {
  install -Dm755 "$srcdir/build/shinoa" "$pkgdir/usr/bin/shinoa"
  install -Dm755 "$srcdir/build/_deps/tdlib-build/libtdjson.so.1.8.63" \
    "$pkgdir/usr/lib/libtdjson.so.1.8.63"
  ln -sf libtdjson.so.1.8.63 "$pkgdir/usr/lib/libtdjson.so"
  install -Dm644 "$srcdir/shinoa/README.md" "$pkgdir/usr/share/doc/$pkgname/README.md"
}