107 lines
3.0 KiB
CMake
107 lines
3.0 KiB
CMake
cmake_minimum_required(VERSION 3.21)
|
|
|
|
project(shinoa VERSION 0.1.0 LANGUAGES CXX)
|
|
|
|
set(CMAKE_CXX_STANDARD 17)
|
|
set(CMAKE_CXX_STANDARD_REQUIRED ON)
|
|
set(CMAKE_CXX_EXTENSIONS OFF)
|
|
|
|
find_program(CLANG_FORMAT_BIN clang-format)
|
|
|
|
include(FetchContent)
|
|
|
|
option(TELEGRAM_TUI_USE_SYSTEM_TDLIB "Use an installed TDLib package instead of fetching it." OFF)
|
|
|
|
set(CURSES_NEED_WIDE TRUE)
|
|
find_package(Curses REQUIRED)
|
|
|
|
set(TELEGRAM_TUI_APP_CONFIG_PATH "")
|
|
if(DEFINED ENV{XDG_DATA_HOME} AND NOT "$ENV{XDG_DATA_HOME}" STREQUAL "")
|
|
set(TELEGRAM_TUI_APP_CONFIG_PATH "$ENV{XDG_DATA_HOME}/telegram-tui/config.json")
|
|
elseif(DEFINED ENV{HOME} AND NOT "$ENV{HOME}" STREQUAL "")
|
|
set(TELEGRAM_TUI_APP_CONFIG_PATH "$ENV{HOME}/.local/share/telegram-tui/config.json")
|
|
endif()
|
|
|
|
set(TELEGRAM_TUI_BUILD_API_ID "")
|
|
set(TELEGRAM_TUI_BUILD_API_HASH "")
|
|
if(TELEGRAM_TUI_APP_CONFIG_PATH AND EXISTS "${TELEGRAM_TUI_APP_CONFIG_PATH}")
|
|
file(READ "${TELEGRAM_TUI_APP_CONFIG_PATH}" TELEGRAM_TUI_APP_CONFIG_JSON)
|
|
|
|
string(REGEX MATCH "\"api_id\"[ \t\r\n]*:[ \t\r\n]*\"?([0-9]+)\"?"
|
|
TELEGRAM_TUI_APP_CONFIG_API_ID_MATCH "${TELEGRAM_TUI_APP_CONFIG_JSON}")
|
|
if(CMAKE_MATCH_1)
|
|
set(TELEGRAM_TUI_BUILD_API_ID "${CMAKE_MATCH_1}")
|
|
endif()
|
|
|
|
string(REGEX MATCH "\"api_hash\"[ \t\r\n]*:[ \t\r\n]*\"([^\"]+)\""
|
|
TELEGRAM_TUI_APP_CONFIG_API_HASH_MATCH "${TELEGRAM_TUI_APP_CONFIG_JSON}")
|
|
if(CMAKE_MATCH_1)
|
|
set(TELEGRAM_TUI_BUILD_API_HASH "${CMAKE_MATCH_1}")
|
|
endif()
|
|
endif()
|
|
|
|
configure_file(
|
|
${CMAKE_SOURCE_DIR}/src/build_config.h.in
|
|
${CMAKE_CURRENT_BINARY_DIR}/build_config.h
|
|
@ONLY
|
|
)
|
|
|
|
if(TELEGRAM_TUI_USE_SYSTEM_TDLIB)
|
|
find_package(Td REQUIRED)
|
|
else()
|
|
set(TD_ENABLE_JNI OFF CACHE BOOL "" FORCE)
|
|
set(TD_ENABLE_DOTNET OFF CACHE BOOL "" FORCE)
|
|
set(TD_ENABLE_TESTS OFF CACHE BOOL "" FORCE)
|
|
set(TD_ENABLE_BENCHMARKS OFF CACHE BOOL "" FORCE)
|
|
set(TD_ENABLE_INSTALL OFF CACHE BOOL "" FORCE)
|
|
set(BUILD_SHARED_LIBS ON CACHE BOOL "" FORCE)
|
|
|
|
FetchContent_Declare(
|
|
tdlib
|
|
GIT_REPOSITORY https://github.com/tdlib/td.git
|
|
GIT_TAG 8921c22f0f85b3cb0b56303f9cba81ba8549f4e8
|
|
GIT_SHALLOW TRUE
|
|
)
|
|
FetchContent_MakeAvailable(tdlib)
|
|
endif()
|
|
|
|
add_executable(
|
|
shinoa
|
|
src/app_attachments.cpp
|
|
src/app_chats.cpp
|
|
src/app_commands.cpp
|
|
src/app.cpp
|
|
src/app_auth.cpp
|
|
src/app_help.cpp
|
|
src/app_input.cpp
|
|
src/app_messages.cpp
|
|
src/app_shell.cpp
|
|
src/app_state.cpp
|
|
src/main.cpp
|
|
src/models.cpp
|
|
src/td_client.cpp
|
|
src/util.cpp
|
|
)
|
|
|
|
if(CLANG_FORMAT_BIN)
|
|
file(GLOB_RECURSE SHINOA_FORMAT_SOURCES CONFIGURE_DEPENDS
|
|
src/*.cpp
|
|
src/*.h
|
|
)
|
|
add_custom_target(
|
|
format
|
|
COMMAND ${CLANG_FORMAT_BIN} -i ${SHINOA_FORMAT_SOURCES}
|
|
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
|
|
COMMENT "Formatting C++ sources with clang-format"
|
|
)
|
|
endif()
|
|
|
|
target_include_directories(shinoa PRIVATE ${CURSES_INCLUDE_DIRS} ${CMAKE_CURRENT_BINARY_DIR})
|
|
target_link_libraries(shinoa PRIVATE ${CURSES_LIBRARIES})
|
|
|
|
if(TELEGRAM_TUI_USE_SYSTEM_TDLIB)
|
|
target_link_libraries(shinoa PRIVATE Td::TdJson)
|
|
else()
|
|
target_link_libraries(shinoa PRIVATE Td::TdJson)
|
|
endif()
|