shinoa/CMakeLists.txt

cmake_minimum_required(VERSION 3.21)

project(shinoa VERSION 0.1.2 LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

find_program(CLANG_FORMAT_BIN clang-format)
find_package(Git QUIET)

include(FetchContent)

option(TELEGRAM_TUI_USE_SYSTEM_TDLIB "Use an installed TDLib package instead of fetching it." OFF)
option(TELEGRAM_TUI_REQUIRE_BUILD_CREDENTIALS
       "Fail configure if build credentials are not provided." OFF)
set(TELEGRAM_TUI_TDLIB_ROOT ""
    CACHE PATH "Path to a prebuilt TDLib root containing include/ and lib/ directories.")

set(CURSES_NEED_WIDE TRUE)
find_package(Curses REQUIRED)
find_package(Threads REQUIRED)

find_package(nlohmann_json QUIET)
if(NOT nlohmann_json_FOUND)
  FetchContent_Declare(
    nlohmann_json
    GIT_REPOSITORY https://github.com/nlohmann/json.git
    GIT_TAG v3.11.3
    GIT_SHALLOW TRUE
  )
  FetchContent_MakeAvailable(nlohmann_json)
endif()

set(TELEGRAM_TUI_APP_CONFIG_PATH "")
if(DEFINED ENV{XDG_DATA_HOME} AND NOT "$ENV{XDG_DATA_HOME}" STREQUAL "")
  set(TELEGRAM_TUI_APP_CONFIG_PATH "$ENV{XDG_DATA_HOME}/telegram-tui/config.json")
elseif(DEFINED ENV{HOME} AND NOT "$ENV{HOME}" STREQUAL "")
  set(TELEGRAM_TUI_APP_CONFIG_PATH "$ENV{HOME}/.local/share/telegram-tui/config.json")
endif()

set(TELEGRAM_TUI_BUILD_API_ID "")
set(TELEGRAM_TUI_BUILD_API_HASH "")
set(TELEGRAM_TUI_BUILD_VERSION "${PROJECT_VERSION}")
set(TELEGRAM_TUI_BUILD_COMMIT "")
if(GIT_FOUND AND EXISTS "${CMAKE_SOURCE_DIR}/.git")
  execute_process(
    COMMAND "${GIT_EXECUTABLE}" rev-parse --short HEAD
    WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
    OUTPUT_VARIABLE TELEGRAM_TUI_BUILD_COMMIT
    OUTPUT_STRIP_TRAILING_WHITESPACE
    ERROR_QUIET
  )
  execute_process(
    COMMAND "${GIT_EXECUTABLE}" describe --tags --always --dirty
    WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
    OUTPUT_VARIABLE TELEGRAM_TUI_GIT_DESCRIBE
    OUTPUT_STRIP_TRAILING_WHITESPACE
    ERROR_QUIET
  )
  if(TELEGRAM_TUI_GIT_DESCRIBE)
    set(TELEGRAM_TUI_BUILD_VERSION "${PROJECT_VERSION}+${TELEGRAM_TUI_GIT_DESCRIBE}")
  endif()
endif()
if(DEFINED ENV{TELEGRAM_TUI_BUILD_API_ID} AND NOT "$ENV{TELEGRAM_TUI_BUILD_API_ID}" STREQUAL "")
  set(TELEGRAM_TUI_BUILD_API_ID "$ENV{TELEGRAM_TUI_BUILD_API_ID}")
elseif(DEFINED ENV{TELEGRAM_API_ID} AND NOT "$ENV{TELEGRAM_API_ID}" STREQUAL "")
  set(TELEGRAM_TUI_BUILD_API_ID "$ENV{TELEGRAM_API_ID}")
endif()

if(DEFINED ENV{TELEGRAM_TUI_BUILD_API_HASH} AND NOT "$ENV{TELEGRAM_TUI_BUILD_API_HASH}" STREQUAL "")
  set(TELEGRAM_TUI_BUILD_API_HASH "$ENV{TELEGRAM_TUI_BUILD_API_HASH}")
elseif(DEFINED ENV{TELEGRAM_API_HASH} AND NOT "$ENV{TELEGRAM_API_HASH}" STREQUAL "")
  set(TELEGRAM_TUI_BUILD_API_HASH "$ENV{TELEGRAM_API_HASH}")
endif()

if((TELEGRAM_TUI_BUILD_API_ID STREQUAL "" OR TELEGRAM_TUI_BUILD_API_HASH STREQUAL "") AND
   TELEGRAM_TUI_APP_CONFIG_PATH AND EXISTS "${TELEGRAM_TUI_APP_CONFIG_PATH}")
  file(READ "${TELEGRAM_TUI_APP_CONFIG_PATH}" TELEGRAM_TUI_APP_CONFIG_JSON)

  if(TELEGRAM_TUI_BUILD_API_ID STREQUAL "")
    string(REGEX MATCH "\"api_id\"[ \t\r\n]*:[ \t\r\n]*\"?([0-9]+)\"?"
           TELEGRAM_TUI_APP_CONFIG_API_ID_MATCH "${TELEGRAM_TUI_APP_CONFIG_JSON}")
    if(CMAKE_MATCH_1)
      set(TELEGRAM_TUI_BUILD_API_ID "${CMAKE_MATCH_1}")
    endif()
  endif()

  if(TELEGRAM_TUI_BUILD_API_HASH STREQUAL "")
    string(REGEX MATCH "\"api_hash\"[ \t\r\n]*:[ \t\r\n]*\"([^\"]+)\""
           TELEGRAM_TUI_APP_CONFIG_API_HASH_MATCH "${TELEGRAM_TUI_APP_CONFIG_JSON}")
    if(CMAKE_MATCH_1)
      set(TELEGRAM_TUI_BUILD_API_HASH "${CMAKE_MATCH_1}")
    endif()
  endif()
endif()

if(TELEGRAM_TUI_REQUIRE_BUILD_CREDENTIALS AND
   (TELEGRAM_TUI_BUILD_API_ID STREQUAL "" OR TELEGRAM_TUI_BUILD_API_HASH STREQUAL ""))
  message(FATAL_ERROR
    "Build credentials are required. Set TELEGRAM_TUI_BUILD_API_ID and "
    "TELEGRAM_TUI_BUILD_API_HASH (or TELEGRAM_API_ID/TELEGRAM_API_HASH).")
endif()

configure_file(
  ${CMAKE_SOURCE_DIR}/src/build_config.h.in
  ${CMAKE_CURRENT_BINARY_DIR}/build_config.h
  @ONLY
)

if(TELEGRAM_TUI_TDLIB_ROOT)
  find_path(TELEGRAM_TUI_TDLIB_INCLUDE_DIR
    NAMES td/telegram/td_json_client.h
    PATHS "${TELEGRAM_TUI_TDLIB_ROOT}/include"
    NO_DEFAULT_PATH
    REQUIRED
  )
  find_library(TELEGRAM_TUI_TDLIB_LIBRARY
    NAMES tdjson libtdjson.so
    PATHS "${TELEGRAM_TUI_TDLIB_ROOT}/lib"
    NO_DEFAULT_PATH
    REQUIRED
  )

  add_library(TdJsonPrebuilt SHARED IMPORTED GLOBAL)
  set_target_properties(TdJsonPrebuilt PROPERTIES
    IMPORTED_LOCATION "${TELEGRAM_TUI_TDLIB_LIBRARY}"
    INTERFACE_INCLUDE_DIRECTORIES "${TELEGRAM_TUI_TDLIB_INCLUDE_DIR}"
  )
  add_library(Td::TdJson ALIAS TdJsonPrebuilt)
elseif(TELEGRAM_TUI_USE_SYSTEM_TDLIB)
  find_package(Td REQUIRED)
else()
  set(TD_ENABLE_JNI OFF CACHE BOOL "" FORCE)
  set(TD_ENABLE_DOTNET OFF CACHE BOOL "" FORCE)
  set(TD_ENABLE_TESTS OFF CACHE BOOL "" FORCE)
  set(TD_ENABLE_BENCHMARKS OFF CACHE BOOL "" FORCE)
  set(TD_ENABLE_INSTALL OFF CACHE BOOL "" FORCE)
  set(BUILD_SHARED_LIBS ON CACHE BOOL "" FORCE)

  FetchContent_Declare(
    tdlib
    GIT_REPOSITORY https://github.com/tdlib/td.git
    GIT_TAG 8921c22f0f85b3cb0b56303f9cba81ba8549f4e8
    GIT_SHALLOW TRUE
  )
  FetchContent_MakeAvailable(tdlib)
endif()

add_executable(
  shinoa
  src/app_attachments.cpp
  src/app_chats.cpp
  src/app_commands.cpp
  src/app.cpp
  src/app_auth.cpp
  src/app_help.cpp
  src/app_input.cpp
  src/app_messages.cpp
  src/app_shell.cpp
  src/app_state.cpp
  src/main.cpp
  src/models.cpp
  src/td_client.cpp
  src/util.cpp
)

if(CLANG_FORMAT_BIN)
  file(GLOB_RECURSE SHINOA_FORMAT_SOURCES CONFIGURE_DEPENDS
    src/*.cpp
    src/*.h
  )
  add_custom_target(
    format
    COMMAND ${CLANG_FORMAT_BIN} -i ${SHINOA_FORMAT_SOURCES}
    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
    COMMENT "Formatting C++ sources with clang-format"
  )
endif()

target_include_directories(shinoa PRIVATE ${CURSES_INCLUDE_DIRS} ${CMAKE_CURRENT_BINARY_DIR})
target_link_libraries(shinoa PRIVATE ${CURSES_LIBRARIES} Threads::Threads
                                       nlohmann_json::nlohmann_json)

if(TELEGRAM_TUI_USE_SYSTEM_TDLIB)
  target_link_libraries(shinoa PRIVATE Td::TdJson)
else()
  target_link_libraries(shinoa PRIVATE Td::TdJson)
endif()